Koltlin 1.3.61 - Multi platform project - Default Idea project - Not able to run java test in jvmTests

Multiplatform
1

HI,
I created a multiplatform project using Intellij2019.3.1. The project contains only default sample classes created by Idea. I am trying to run a unit test in javaTest but it’s fail with FAILURE: Build failed with an exception.

* What went wrong:
Execution failed for task ':jvmTest'.
> No tests found for given includes: [sample.TestJava](filter.includeTestsMatching)

Please see the build.gradle file which was created by Idea by default

plugins {
    id 'org.jetbrains.kotlin.multiplatform' version '1.3.61'
}
repositories {
    mavenCentral()
}
group 'com.example'
version '0.0.1'

apply plugin: 'maven-publish'

kotlin {
    jvm()
    js {
        browser {
        }
        nodejs {
        }
    }
    // For ARM, should be changed to iosArm32 or iosArm64
    // For Linux, should be changed to e.g. linuxX64
    // For MacOS, should be changed to e.g. macosX64
    // For Windows, should be changed to e.g. mingwX64
    macosX64("macos")
    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin('stdlib-common')
            }
        }
        commonTest {
            dependencies {
                implementation kotlin('test-common')
                implementation kotlin('test-annotations-common')
            }
        }
        jvmMain {
            dependencies {
                implementation kotlin('stdlib-jdk8')
            }
        }
        jvmTest {
            dependencies {
                implementation kotlin('test')
                implementation kotlin('test-junit')
                // implementation kotlin("org.junit.jupiter:junit-jupiter-api:5.3.2")
                //implementation kotlin("org.junit.jupiter:junit-jupiter-engine:5.3.2")

            }
        }
        jsMain {
            dependencies {
                implementation kotlin('stdlib-js')
            }
        }
        jsTest {
            dependencies {
                implementation kotlin('test-js')
            }
        }
        macosMain {
        }
        macosTest {
        }
    }
}

I am struggling with the issue for couple of days but I could not figure out the issue.
Could someone please help ( kotlin tests *.kt run fine though)

2

By default, Java sources are not supported in MPP project. You have to add the support explicitly using withJava() DSL: https://kotlinlang.org/docs/reference/building-mpp-with-gradle.html#java-support-in-jvm-targets. Please try it.

2 Likes
3

@Alexey.Belkov
I tried as you suggested and it worked. Thanks a lot.
I explicitly added withJava() and added the test in java folder as I shown in the attached screenshot.
Please see my build.gradle incase someone needs

Screenshot 2020-01-20 at 11.03.22
Screenshot 2020-01-20 at 11.03.22614×1086 51.6 KB 

plugins {
    id 'org.jetbrains.kotlin.multiplatform' version '1.3.61'
}
repositories {
    mavenCentral()
}
group 'com.example'
version '0.0.1'

apply plugin: 'maven-publish'

kotlin {
    jvm{
        withJava()
    }

    js {
        browser {
        }
        nodejs {
        }
    }
    // For ARM, should be changed to iosArm32 or iosArm64
    // For Linux, should be changed to e.g. linuxX64
    // For MacOS, should be changed to e.g. macosX64
    // For Windows, should be changed to e.g. mingwX64
    macosX64("macos")
    sourceSets {
        commonMain {
            dependencies {
                implementation kotlin('stdlib-common')
            }
        }
        commonTest {
            dependencies {
                implementation kotlin('test-common')
                implementation kotlin('test-annotations-common')
            }
        }
        jvmMain {
            dependencies {
                implementation kotlin('stdlib-jdk8')
            }
        }
        jvmTest {
            dependencies {
                implementation kotlin('test')
                implementation kotlin('test-junit')
            }
        }
        jsMain {
            dependencies {
                implementation kotlin('stdlib-js')
            }
        }
        jsTest {
            dependencies {
                implementation kotlin('test-js')
            }
        }
        macosMain {
        }
        macosTest {
        }
    }
}
2 Likes